How delete duplicates from array?

[Alina]

Good day!
I have an Array.

Code: Select all

GetClipBoard>List,0
Separate>List,CRLF,Array1

How can I delete duplicates from the array and stay only uniq values?

[Grovkillen]

Loop through the array and add new value to another string.

Code: Select all

GetClipBoard>List,0
Separate>List,CRLF,Array1
Let>uniqueList=
Let>k=0
Repeat>k
  Let>k=k+1
  Let>tempValue=Array1_%k%  
  Position>tempValue,uniqueList,1,foundValue,False
  If>foundValue=0
    Let>uniqueList=%uniqueList%|
  EndIf>
Until>k=Array1_count
Separate>uniqueList,|,Array2

The last value of the Array2 will be empty though. And please be aware that I wrote this on the phone and on top of my head... Syntax might be remembered incorrectly etc.

[Alina]

Thank you!

Program writes "Error in Position Command" in this string:
Position>tempValue,uniqueList,1,foundValue,False

And in this string uniqueList= must be empty?
Let>uniqueList=

[Grovkillen]

Yes you need to declare the empty string first. Look in the manual to get the correct syntax for the position command.

[Alina]

Mistake's disappeared.
But result of macros is empty unfortunately,
MessageModal>Array2_%x% - this string gives empty.

Code: Select all

GetClipBoard>List,0
Separate>List,CRLF,Array1

Let>uniqueList=

Let>k=0
Repeat>k
Let>k=k+1

Let>tempValue=Array1_%k%
  Position>tempValue,uniqueList,1,foundValue,FALSE
  If>foundValue=0
    Let>uniqueList=%uniqueList%|
  EndIf>

MessageModal>Array1_%k%
Until>k=Array1_count



Separate>uniqueList,|,Array2
Let>x=0
Repeat>x
Let>x=x+1
MessageModal>Array2_%x%
Until>x=Array2_count

[Grovkillen]

Use the variable inspector and step though your script using F8.

[Dorian (MJT support)]

Grovkillen is on his phone, and I must say he did a better job than I could have done off the top of my head.

I think part of the problem was that %tempValue% wasn't being appended to %uniqueList%. The Position error you mentioned happens when the last array item is blank, so if you're selecting a blank line at the end of your selection and then copying it to the clipboard.

Code: Select all

GetClipBoard>List,0
Separate>List,CRLF,Array1
Let>uniqueList=
Let>k=0

Repeat>k
  Let>k=k+1
  Let>tempValue=Array1_%k%
  Position>tempValue,uniqueList,1,foundValue,FALSE
  If>foundValue=0
    Let>uniqueList=%tempValue%|%uniqueList%
  EndIf>
  MessageModal>Array1_%k%
Until>k=Array1_count

Separate>uniqueList,|,Array2
Let>x=0
Repeat>x
Let>x=x+1
MessageModal>Array2_%x%
Until>x=Array2_count

[Grovkillen]

Ah, that was one very important error on my part

[Alina]

Grovkillen and Dorian Thank you very much!
Grovkillen, macros is great and very useful Dorian, without your help I could not run macros .

[Dorian (MJT support)]

Here's a self contained version in case it helps anyone else.

I've tweaked it a bit so if the last item in Array1 is blank, it subtracts 1 from Array1_Count. This means it won't process the last item if it's blank, and we won't get the Pos error.

Also seeing as the last item in Array2 is always blank, we can always ignore the last item. We can do that with a Complex Expression. As you can see the last line is

Code: Select all

Until>x={(%Array2_count%-1)}

Code: Select all

/*
TheList:
fish
horse
dog
horse
fish
*/

LabelToVar>TheList,List
PutClipBoard>List

GetClipBoard>List,0
Separate>List,CRLF,Array1

//If last item is blank, ignore it
Let>LastArrayItemNum=Array1_Count
if>Array1_%LastArrayItemNum%=
  Let>Array1_Count=Array1_Count-1
endif

Let>uniqueList=
Let>k=0

Repeat>k
  Let>k=k+1
  Let>tempValue=Array1_%k%
  Position>tempValue,uniqueList,1,foundValue,FALSE
  If>foundValue=0
    Let>uniqueList=%tempValue%|%uniqueList%
  EndIf>
  MessageModal>Array1_%k%
Until>k=Array1_count

Separate>uniqueList,|,Array2
Let>Array2_count=Array2_count-1

Let>x=0
Repeat>x
Let>x=x+1
MessageModal>Array2_%x%
Until>x={(%Array2_count%-1)}