Invoke Quicklaunch via popupmenu?

[ari]

Is there a way to invoke the actual quicklaunch under my mouse pointer, like the popupmenu command? Also, can quicklaunch be opened via a hotkey?

[Marcus Tettmar]

Not sure what you mean. Can you clarify?

[ari]

Sure, is there a way to see the quicklaunch pop-up menu in other areas of the screen, perhaps triggered by a hotkey or some other command. Basically like the popupmenu command, except with the quicklaunch content. Like a quicklaunch plugin for the popupmenu command.

[JRL]

Something like this? This script views the macros12.dat file and puts every script that has the quicklaunch flag set to "Y" in a list. It then presents that list in a dialog. Double click on an item in the list and it should execute the script.

I'm pretty sure this will not work correctly if you have your scripts in a directory structure or somewhere other than the default script directory so let us know if this doesn't work for you.

Code: Select all

ReadFile>%script_dir%\macros12.dat,vData
Separate>vData,crlf,vLine

Let>vList=
Let>kk=0
Repeat>kk
  Add>kk,1
  Let>value=vLine_%kk%
  Separate>value,:,item
  If>item_24=Y
    Concat>vList,%item_1%%crlf%
  EndIf
Until>kk=vLine_Count


Dialog>Dialog1
object Dialog1: TForm
  Caption = 'QuickLaunch'
  ClientHeight = 526
  ClientWidth = 368
  Position = poScreenCenter
  object MSListBox1: tMSListBox
    Left = 14
    Top = 14
    Width = 339
    Height = 499
    Anchors = [akLeft, akTop, akRight]
  end
end
EndDialog>Dialog1

SetDialogProperty>Dialog1,MSListBox1,Text,vList
AddDialogHandler>Dialog1,MSListBox1,OnDblClick,RunScript

Show>Dialog1,

SRT>RunScript
  GetDialogProperty>Dialog1,MSListBox1,SelectedItems,script
  ExecuteFile>%script_dir%\%script%.scp
  Exit>0
END>RunScript