Exchange Sort, Insert Sort, or Quicksort?

[azzkicker_9002]

I'm using MS to sort the contents of a .csv file, I found a quick and simple method in one of the posts, the bubble sort algorithm. It works well with small lists, but is not practical for large lists.

I tried using excel, but it messes up .csv files on saving. Besides, I sometimes need to review the results while its working and that causes file access errors.

I would appreciate it if someone would help me create a function that performs quicksort algorithm. More info and pseudo code is at: http://en.wikipedia.org/wiki/Quicksort

If there's an alternative native function in windows API or some DLL that I could download, I'd appreciate it if someone could point me in the right direction and show me how to integrate it into my macro.

Thank you for an excellent product.

[JRL]

I don't have time right now to look into this properly but have you tried DOS sort? Open a command window and type "sort /?" for usage.

[Marcus Tettmar]

I adapted the non-recursive Quicksort PHP function found here:
http://www.algorithmist.com/index.php/Q ... ursive.php

Code: Select all

GetFileList>%WIN_DIR%\*.*,files
Separate>files,;,array

/*
Let>array_1=Yellow
Let>array_2=Apple
Let>array_3=Blue
Let>array_4=White
Let>array_5=Azure
Let>array_count=5
*/

If>array_count>0

 Let>cur=1
 Let>stack[1]['l']=1
 Let>stack[1]['r']=array_count

 Repeat>cur

  Let>l=stack[%cur%]['l']
  Let>r=stack[%cur%]['r']
  Let>cur=cur-1

  Label>lloop

   Let>i=l
   Let>j=r
   Let>pivot={(%l%+%r%) div 2}
   Let>tmp=array_%pivot%

   Label>iloop
    Label>left
      Let>this=array_%i%
      If>{%this%<%tmp%}
        Let>i=i+1
        Goto>left
      Endif

    Label>right
      Let>this=array_%j%
      If>{%tmp%<%this%}
        Let>j=j-1
        Goto>right
      Endif

    If>{%i%<=%j%}
     Let>w=array_%i%
     Let>array_%i%=array_%j%
     Let>array_%j%=w

     Let>i=i+1
     Let>j=j-1
    Endif
    If>{%i%<=%j%},iloop
    Endif

   If>i<r
    Let>cur=cur+1
    Let>stack[%cur%]['l']=i
    Let>stack[%cur%]['r']=r
   Endif
   Let>r=j

  If>l<r,lloop
  Endif

 Until>cur=1

Endif

[OrangeAndBlue]

Just a heads up, I think you want the loop termination condition to be:

Code: Select all

Until>cur=0